Software of the Month Club 1999 July/Software of the Month - Ultimate Collection Shareware 263.iso/pc/Xtras/Widget Wizard/Widget Wizard.dir/00041_Script_Primary Movie Script

Text File | 1997-05-10 | 16KB | 446 lines

--Widget Wiz Programmer: Frances Killam, Digital Muse, [e-mail]
--Widget Wiz Producer and Artist: Lisa Coen, SightOn, [e-mail]
--Widget Wiz Executive Producer: Dianna Wynne, Macromedia.
--Special thanks to Irv Kalb and Kevin Mullet for creating Animation Wiz, which I used for inspiration.
--Special thanks to Andy Rose who wrote most of the behaviors for this project.


global gArtSprite              --sprite channel that button art lives in
global gAltParamList      --current list of alternative art parameters
global gExportList           --list of all castmembers needed for selected button
global gInstructStart       --name of 1st Instruction cast member
global gInstructionsList --text to be stuffed into MIAW Instruct.dir
global gInstructions       --current step being passed to MIAW
global gPasteList           --property list of memberName and script needed for each sprite needed for controller/button/etc...
global gInstructionWindow --MIAW for instructions
global gFirstWindowFlag --boolean flag, False on startMovie, true after MIAW has opened once
global gInstructRect      --current rect location of Instruction Movie
global gInstructStep      --which step are we on? --default, 1
global gInstructTotal     --how many steps are there?
global gWizWindow      --name of the current movie
global gButtonName    --text to be slugged into field "ButtonName"
global LocationList       --List of locations for sprites to be pasted
global gCurrentSprite  -- Sprite number we are currently copying to user's cast
global PasteInfoList     --Info needed to generate score in user's cast
global gSpriteCount     --The total number of sprites used per controller
global gSpritePhrase   --plural or singular version of text : sprite, acc to gSpriteCount
global gUserSelection --User's selection on stage
global gFrameCountMin  --Minimum number of frames we will paste into user's score
global gFrameCountMax  --Maximum number of frames we will paste into user's score
global gStartFrame        --Frame where we will begin recording in user's score
global gStartSprite         --Sprite where we will begin recording in user's score
global gExportScriptList --List of all the scripts exported to user's cast

--edited 3/6/97, fmk
--removed redundant script checking, 3/6/97, fmk
--added redundant script checking, but only on a widget by widget basis, 3/12/97, fmk
--added centering code, 3/19/97, fmk
--fixed negative sprite selection bug, 4/14/97, fmk

on startMovie

  set gArtSprite = 24
  set gFirstWindowFlag = FALSE
  set gWizWindow = the movieName
  set gExportScriptList = [ ]

  go to frame 1
end startMovie



on stopMovie
  cursor(-1)
  forgetInstructions
  if objectP(window gWizWindow) then forget window gWizWindow
end stopMovie


on closeWindow
  set myName = the movieName
  set offS = offset( ".dir", myName )
  if offS then
    delete char offS to (offS + 4) of myName
  end if
  forget window myName
end closeWindow


on validateUserSelection
  set gCurrentSprite = 24 --starting sprite to copy
  set gFrameCountMin = 5
  set gFrameCountMax = 15
  set mySprite = gCurrentSprite
  set myFlag = TRUE
  set gSpriteCount = 0

  --1st, see how many channels we need for our selection
  repeat while myFlag = TRUE

    if the type of sprite mySprite = 0 then
      if the type of sprite (mySprite + 1) = 0 then --we're done
        set myFlag = FALSE
        exit repeat
      else --we're not done, we have a valid channel, so count it
        set gSpriteCount = gSpriteCount + 1
        set mySprite = mySprite + 1
      end if
    else -- we have a valid channel, so count it
      set gSpriteCount = gSpriteCount + 1
      set mySprite = mySprite + 1
    end if
  end repeat

  if gSpriteCount = 1 then set gSpritePhrase = "channel"
  else set gSpritePhrase = "channels"

  --next, get the user's selection
  tell the stage
    set gUserSelection = the scoreSelection
  end tell

  --next check to see if selection is the right size
  if gUserSelection = [] then --has a selection been made?

    alert "Please click in the score where you want the widget to begin, then try again.  You need " && gSpriteCount && "sprite"  && gSpritePhrase &&  "and at least" && gFrameCountMin && "frames. "
    abort
  end if

  set gStartSprite = getAt(getAt(gUserSelection, 1), 1)
  set myEndSprite = (gStartSprite + gSpriteCount) - 1

  set gStartFrame = getAt(getAt(gUserSelection, 1), 3)
  set myEndFrame = (gStartFrame + gFrameCountMax) - 1

  if gStartSprite < 1 then   --does selection start > 0?
    alert "Your selection must start in sprite channel 1 or greater.  Please make a new selection and try again."
    abort
  end if


  tell the stage --Check the selection, is it empty?

    repeat with y = gStartFrame to myEndFrame
      set myFrameCounter = y - gStartFrame
      go to frame y

      repeat with z = gStartSprite to myEndSprite

        if the type of sprite z <> 0 then --we have something in the selection, alert not valid!

          --check to see where we are btwn gFrameCountMin and gFrameCountMax

          if myFrameCounter < gFrameCountMin then --we don't have enough frames free to write widget.

            alert "This selection contains something already.  You need " && gSpriteCount && "sprite" && gSpritePhrase &&  "and at least" && gFrameCountMin && "frames.  Please click in the score where you want the widget to begin, then try again."
            abort
          else --we have enough empty frames to write the widget
            set gFrameCountMax = myFrameCounter
            set myEndFrame = myFrameCounter - 1 --this should bump us out of frameCount repeat
            exit repeat
          end if
        end if
      end repeat
    end repeat

    go to frame gStartFrame
  end tell

  copyButtonPrime
end validateUserSelection


on copyButtonPrime

  cursor 4

  --initialize widget for copying
  go the frame + 1
  go the frame - 1

  --initialize our vars and lists
  set myMemberNum = 1 --starting castMember to look at for copying
  set PasteInfoList = []

  set mySpriteList = [ ]

  set myWidgetScriptList = []
  set myAssocPasteList = []

  --  set myRedundantFlag = FALSE

  repeat with x = gCurrentSprite to ((gCurrentSprite + gSpriteCount) - 1)

    --find out what i have to copy... me, myAssociates, myscript
    --set up data list
    set myRecord = [#MemberName:"", #MemberNumber:0, #ScriptName:"", #ScriptNumber:0, #MemberLoc:point(0,0), #MemberRect:rect(0, 0, 0, 0), #Onstage:0]

    if the type of sprite x <> 0 then
      set the MemberName of myRecord = the name of member(the member of sprite x)
      set the MemberLoc of myRecord = the loc of sprite x
      set the MemberRect of myRecord = the rect of sprite x

      --paste me to user's cast
      copyToClipboard member  (the member of sprite x)

      tell the stage
        --determine where in the user's cast to paste our sprites
        --currently, we paste into castLib 1 ONLY
        repeat while the type of member myMemberNum of castLib 1 <> #empty
          set myMemberNum = myMemberNum + 1
        end repeat
        pasteClipboardInto member myMemberNum of castLib 1

        set the MemberNumber of myRecord = the number of member myMemberNum of castLib 1
      end tell

      if the scriptNum of sprite x > 0 then

        --paste myAssociates to the user's cast
        set myAssocList = []
        set myAssocList = getAssocMembers (getAt(the scriptInstanceList of sprite x,1))

        --check to see if we have already brought over this list of Assoc Members
        set myAssocPasteIndex = 0
        repeat with r = 1 to count(myAssocPasteList)
          if myAssocList = getAt(myAssocPasteList, r) then set myAssocPasteIndex = r
        end repeat

        if myAssocPasteIndex = 0 then --we don't have this list of Assoc Members yet, so paste them
          repeat with a = 1 to count(myAssocList )
            copyToClipboard member  (getAt(myAssocList, a))

            tell the stage
              --determine where in the user's cast to paste our sprites
              repeat while the type of member myMemberNum of castLib 1 <> #empty
                set myMemberNum = myMemberNum + 1
              end repeat
              pasteClipboardInto member myMemberNum of castLib 1
            end tell
          end repeat

          add myAssocPasteList, myAssocList
        end if

        --paste myScript to user's cast
        set myScriptName = the name of member(the scriptNum of sprite x)
        set the ScriptName of myRecord = myScriptName

        --check to see if this script is duplicated within this particular widget
        set myWidgetScriptIndex = 0
        repeat with q = 1 to count(myWidgetScriptList)
          if the ScriptName of getAt(myWidgetScriptList, q) = myScriptName then set myWidgetScriptIndex = q
        end repeat

        if myWidgetScriptIndex = 0 then --my script is unique to the widget, so copy it to the user's cast
          copyToClipboard member  (the scriptNum of sprite x)

          set myWidgetScriptRecord = [#ScriptName:"", #ScriptNumber:0]
          set the ScriptName of myWidgetScriptRecord = myScriptName


          tell the stage
            --determine where in the user's cast to paste our sprites
            repeat while the type of member myMemberNum of castLib 1 <> #empty
              set myMemberNum = myMemberNum + 1
            end repeat
            pasteClipboardInto member myMemberNum of castLib 1

            set myScriptNumber = the number of member myMemberNum of castLib 1

            set the ScriptNumber of myRecord = myScriptNumber
            set the ScriptNumber of myWidgetScriptRecord = myScriptNumber

          end tell

          add myWidgetScriptList, myWidgetScriptRecord

        else --another sprite in my widget already uses this script, so we don't need to copy it again.  Use the  script we already have for the current sprite.

          set the ScriptNumber of myRecord = the ScriptNumber of getAt(myWidgetScriptList, myWidgetScriptIndex)
        end if

      end if
    end if

    add PasteInfoList, myRecord

  end repeat

  --now check for the frame script
  set myFrameScriptName = "loop current frame"

  copyToClipboard member  myFrameScriptName

  tell the stage
    --determine where in the user's cast to paste our sprites
    repeat while the type of member myMemberNum of castLib 1 <> #empty
      set myMemberNum = myMemberNum + 1
    end repeat
    pasteClipboardInto member myMemberNum of castLib 1

    set myFrameScriptNum = the number of member myMemberNum of castLib 1
    set myScriptRecord = [#ScriptName: myFrameScriptName, #ScriptNumber: myFrameScriptNum]
    add gExportScriptList, myScriptRecord
  end tell

  --  put "PasteInfoList = " & PasteInfoList --DEBUG
  --  put "gExportScriptList = " & gExportScriptList --DEBUG

  -- Determine the bounding rect for Widget on Wizard stage
  set myTestRect = rect(1, 1, 496, 342)
  set myPlacementFlag = FALSE

  repeat with s = 1 to count(PasteInfoList)
    set myCurrentRect = the MemberRect of getAt(PasteInfoList, s)
    --is this sprite on stage?
    if union(myTestRect, myCurrentRect) = myTestRect then --we're on stage
      if myPlacementFlag = FALSE then
        set myPlacementFlag = TRUE
        set myBoundingRect = myCurrentRect
      else
        set myBoundingRect = union(myBoundingRect, myCurrentRect)
      end if

      set the Onstage of getAt(PasteInfoList, s) = 1

    end if
  end repeat


  -- Determine location for bounding rect on user's stage
  set myBoundingWidth = getAt(myBoundingRect, 3) - getAt(myBoundingRect, 1)
  set myBoundingHeight = getAt(myBoundingRect, 4) - getAt(myBoundingRect, 2)
  tell the stage
    set myStageWidth = the stageRight - the stageLeft
    set myStageHeight = the stageBottom - the stageTop
  end tell
  --figure out the starting point of the rect we will paste into on the user's stage
  set myStartH = (myStageWidth - myBoundingWidth) / 2
  set myStartV = (myStageHeight - myBoundingHeight) / 2
  --figure out the starting point of our Bounding rect
  set myBoundingH = getAt(myBoundingRect, 1)
  set myBoundingV = getAt(myBoundingRect, 2)

  --next, use score generation to place required castMembers on user's score

  tell the stage

    beginRecording

      repeat with y = gStartFrame to (gStartFrame + gFrameCountMax) - 1 --do this for each frame

        set myListCount = 1

        go to frame y

        if the frame = (gStartFrame + gFrameCountMax) - 1 then      --add the frameScript
          set   the frameScript = myFrameScriptNum
        end if

        repeat with z = gStartSprite to (gStartSprite + gSpriteCount) - 1

          set myRecord = getAt(PasteInfoList, myListCount)
          set myListCount = myListCount + 1

          --validate record as having data or not
          if the MemberNumber of myRecord > 0 then

            set the member of sprite z = the MemberNumber of myRecord

            if the Onstage of myRecord = 0 then
              set the loc of sprite z = the MemberLoc of myRecord
            else
              set myMemberH = getAt(the MemberLoc of myRecord, 1)
              set myMemberV = getAt(the MemberLoc of myRecord, 2)
              set myPasteHdif = myMemberH - myBoundingH
              set myPasteVdif = myMemberV - myBoundingV
              set the loc of sprite z = point(myStartH + myPasteHdif, myStartV + myPasteVdif)
            end if

            if the ScriptNumber of myRecord <> 0 then set the scriptNum of sprite z = member (the ScriptNumber of myRecord)

            set the tweened of sprite z to TRUE

          end if

        end repeat

      end repeat

    endRecording
  end tell


  beep(2) --DEBUG

  cursor -1

  --open instruction window
  openInstructionWindow
end copyButtonPrime



on setWindowRect
  if gFirstWindowFlag = FALSE then
    set myLeft = the stageLeft + 50
    set myTop = the stageTop + 50
    -- lisa change window size 2/26/97
    set myWidth = 160
    set myHeight = 400 -- + 15 --for titleBar
    set gInstructRect = rect(myLeft, myTop, myLeft + myWidth, myTop + myHeight)

    set gFirstWindowFlag = TRUE
  end if
end setWindowRect


on openInstructionWindow
  if objectP(gInstructionWindow) then forgetInstructions --forget gInstructionWindow

  setWindowRect

  set gInstructionWindow = window "Instructions"
  set the rect of gInstructionWindow = gInstructRect
  set the fileName of gInstructionWindow = the pathName & "-Instrct.dir"
  set the titleVisible of gInstructionWindow = FALSE
  set the windowType of gInstructionWindow = 49 --palette style
  open gInstructionWindow

  resetInstructText
end openInstructionWindow




on resetInstructText
  tell gInstructionWindow
    displayNewText
  end tell
end resetInstructText


on forgetInstructions
  if objectP(gInstructionWindow) then
    set gFirstWindowFlag = TRUE
    set gInstructRect = the rect of gInstructionWindow
    forget gInstructionWindow
  end if
end forgetInstructions




on initElements
  set gInstructStart = the frameLabel & "-1"
  if objectP(gInstructionWindow) then resetInstructText
end initElements